AndroidIDE/app/build.gradle

apply plugin: 'com.android.application'
apply plugin: 'com.google.gms.google-services'
apply plugin: 'com.google.firebase.crashlytics'

if(rootProject.ext.stringfogEnabled) {
    apply plugin: com.github.megatronking.stringfog.plugin.StringFogPlugin
}

android {
    compileSdkVersion rootProject.ext.compileSdk
	buildToolsVersion rootProject.ext.buildTools
	
    defaultConfig {
        applicationId rootProject.ext.packageName
        minSdkVersion rootProject.ext.minSdk
        targetSdkVersion rootProject.ext.targetSdk
        versionCode rootProject.ext.versionCode
        versionName rootProject.ext.versionName
        
		multiDexEnabled true
		vectorDrawables.useSupportLibrary = true
    }
	
	compileOptions {
		coreLibraryDesugaringEnabled true
		sourceCompatibility rootProject.ext.javaSourceVersion
        targetCompatibility rootProject.ext.javaTargetVersion
	}
    
    aaptOptions {
        additionalParameters "--java", "$buildDir/gen"
    }
	
	lintOptions {
		abortOnError false
		disable "VectorPath",
				"NestedWeights",
				"UnusedResources",
				"ContentDescription",
                "SmallSp"
    }
	
	buildFeatures.viewBinding true
    
    def key = new File("/sdcard/AndroidAppProjects/publishKey.keystore");
    def isKeyAvailable = key.exists()

    if(isKeyAvailable) {
        signingConfigs {
		
            debug {
                storeFile file("/sdcard/AndroidAppProjects/publishKey.keystore")
                storePassword "itsaky"
                keyAlias "itsaky"
                keyPassword "itsaky"
            }
        
            release {
                storeFile file("/sdcard/AndroidAppProjects/publishKey.keystore")
                storePassword "itsaky"
                keyAlias "itsaky"
                keyPassword "itsaky"
            }
        }
    }

    buildTypes {
        debug {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            if(isKeyAvailable) { signingConfig signingConfigs.debug }
        }
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            if(isKeyAvailable) { signingConfig signingConfigs.release }
        }
    }
	
	packagingOptions {
		exclude 'META-INF/eclipse.inf'
		exclude 'about_files/LICENSE-2.0.txt'
		exclude 'plugin.xml'
		exclude 'plugin.properties'
        exclude 'about.mappings'
        exclude 'about.properties'
        exclude 'about.ini'
        exclude 'modeling32.png'
	}
}

if(rootProject.ext.stringfogEnabled) {
    stringfog {
        key 'WVV0aGMwaEFZVzVFVW05SlJFbGtaUT09'
        enable true
        implementation 'com.github.megatronking.stringfog.xor.StringFogImpl'
    }
}

task copyBindings(type: Copy) {
    from "build/generated/data_binding_base_class_source_out/debug/out"
    into 'build/gen'
}

dependencies {
	// Annotation processors
	annotationProcessor 'com.github.bumptech.glide:compiler:4.12.0'
	
	implementation 'com.blankj:utilcodex:1.30.6'
	implementation 'com.elvishew:xlog:1.8.0'
	implementation 'com.github.abhishekti7:UnicornFilePicker:1.0.2'
	implementation 'com.github.bumptech.glide:glide:4.12.0'
	implementation 'com.github.megatronking.stringfog:xor:1.1.0'
	implementation 'com.github.piruin:quickaction:2.4.3'
    implementation 'com.github.Rosemoe:BlockLinkedList:1.0.0'
	implementation 'com.github.smart-fun:XmlToJson:1.5.1'
	
	// Dependencies for java completion
	implementation 'com.google.code.gson:gson:2.8.8'
	implementation 'com.google.guava:guava:30.1.1-android'
	implementation 'org.antlr:antlr4-runtime:4.9.2'
	
    implementation 'org.jsoup:jsoup:1.14.2'
    
	// AndroidX
	implementation 'androidx.annotation:annotation:1.2.0'
	implementation 'androidx.appcompat:appcompat:1.3.1'
	implementation 'androidx.cardview:cardview:1.0.0'
	implementation 'androidx.constraintlayout:constraintlayout:2.1.1'
	implementation 'androidx.coordinatorlayout:coordinatorlayout:1.1.0'
	implementation 'androidx.drawerlayout:drawerlayout:1.1.1'
    implementation 'androidx.gridlayout:gridlayout:1.0.0'
	implementation 'androidx.multidex:multidex:2.0.1'
	implementation 'androidx.preference:preference:1.1.1'
	implementation 'androidx.recyclerview:recyclerview:1.2.1'
	implementation 'androidx.vectordrawable:vectordrawable:1.1.0'
	implementation 'androidx.vectordrawable:vectordrawable-animated:1.1.0'
    implementation 'com.google.android.material:material:1.4.0'
	
	// Firebase
	implementation platform('com.google.firebase:firebase-bom:28.4.2')
	implementation 'com.google.firebase:firebase-analytics'
	implementation 'com.google.firebase:firebase-crashlytics'
	implementation 'com.google.firebase:firebase-messaging'
    
	// Local projects
    implementation project(':sdk-info')
	implementation project(':treeview')
    implementation project(':emulatorview')
    implementation project(':javapoet')
    implementation project(':lsp')
    
    // LSP4J
    implementation 'org.eclipse.lsp4j:org.eclipse.lsp4j:0.12.0'
    
	implementation fileTree(dir: 'libs', include: ['*.jar'])
	
	coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:1.1.5'
}